使用AutoHotKey提高键盘效率

自从自己设计使用了全键可编程小键盘以后，一直琢磨着怎么提高键鼠的使用效率，除了安排好合适的配列外，还用AutoHotKey作为增强工具，效果不错，故分享出来，希望起到抛砖引玉的效果。

AutoHotkey简称AHK，是一款免费开源小程序，通过把常用的键盘鼠标操作编写成脚本语句来动态调用的方式避免了每次手动输入的重复操作，提高键盘效率。

AHK体积小、简单易用，非常适合作为小键盘的增强工具。我主要用它来完成以下操作：
1、最常用的操作：按鼠标左键+右键关闭浏览器标签页，双击中键关闭程序。
2、快速输入一些高频短句，如邮箱、手机号、地址等。例如Layer1右下角的^!#8等。
3、宏操作，如删除一行、删除光标到行首、到行末，虽然QMK可以直接在键盘完成，但AHK更方便编辑。如Layer2的^!#BS、^!#Del等。
4、软件快捷键：如在键盘各层空白位置设置了很多快捷键^!+a、^!+b、^!+c等，可以用AHK设置^!+b浏览百度新闻，^!+c运行Chrome，^!+q运行qq，^!+j运行计算器…… 也可以按住鼠标左键同时点击某字母作为快捷键，对于右手键盘左手鼠标时也很方便。

AHK对于一些简单操作几乎不需要学习即可上手使用，以下是一些例子，有兴趣可以了解并使用，提高效率。

//////////////////////   以下为ahk文件部分内容，供参考   /////////////////////

;将要自启动的快捷方式放到文件夹C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
; #win ^ctrl !alt +shift

;=====开关机、运行程序、打开网页等快捷键=====
^!+#,::run C:\Windows\System32\shutdown.exe -r -t 00    ;重启
^!+#.::run C:\Windows\System32\shutdown.exe -s -t 00    ;关机

^+!b::
~LButton & b::run "C:\Program Files (x86)\Google\Chrome\Application\chrome.exe" --incognito --profile-directory="Default" https://news.baidu.com/

~LButton & LCtrl::^+!1    ;Media hotkey1
~LButton & LWin::^+!2    ;Media hotkey2

;=====剪切、复制等=====
^!#Backspace:: Send +{Home}^c{BS}        ;剪到行首
^!#Del:: Send +{End}^c{delete}                           ;剪到行末
#<^z:: Send ^y
#<^x:: Send {Home}+{End}+{Right}^c{BS}        ;剪切一行
#<^v:: Send {Home}^v            ;粘贴一行
#<^c:: Send {Home}+{End}+{Right}^c        ;复制一行

;=====输入特殊字符串=====        
^!#8::sendraw, 131xxxxxxxx
<^!PgUp::sendraw,xxxxxx@qq.com
<^!PgDn::sendraw,www.jlc.com

;=====鼠标快捷键: 关闭页面、窗口=====
~LButton & RButton::Send,^w
~MButton::                                            ;双击中键关闭当前窗口
if (A_PriorHotkey = "~MButton" and A_TimeSincePriorHotkey < 500)
    subCloseThisWin()
Return  

;=====子程序、函数=====
subCloseThisWin()
{
if (funExistclass("ahk_class WorkerW")=0) 
    Winclose, A  
else Send, !{F4}
return
}

funExistclass(class)  
{  
MouseGetPos,,,win  
WinGet,winid,id,%class%  
if win = %winid%  
    Return,1  
Else  
    Return,0  
}